Перевод NCR в OutOfService

[GOST76]

Господа, какая команда может локально выкинуть банкомат NCR в режим OutOfService, если её (команду) прописать в батнике который гасит Аптру, в таком как killaandc_universal.cmd. Хочу реализовать безопасное выключение банкомата с помощью ИБП если пропало питание.

[olegka_n]

Могу предложить кем то написанный батник, который ослеживает наличии операции и прочего в данный момент, плавно гасит аптру при их остутвии и гасит банкомат.
Батник был заточен именно для гашения банкомата от упса.

[olegka_n]

Код: Выделить всё

@echo off
cls
title APTRA SHUTDOWN (UPS initiated)
echo Shutdown APTRA ATM...

if not exist c:\NCRLogs md c:\NCRLogs
echo --------------- >>c:\NCRLogs\UPSmanage.log
echo UPS start Shutdown ATM: >>c:\NCRLogs\UPSmanage.log
date /T >>c:\NCRLogs\UPSmanage.log
time /T >>c:\NCRLogs\UPSmanage.log

SET STARTUP_MODE=/SDU

rem     ensure the application is not performing a transaction
:STEP2
echo Ensure the application is not performing a transaction...
echo releasing customer resources... >>c:\NCRLogs\UPSmanage.log
SSTManage /LC "APTRA Shutdown" 10000 >>c:\NCRLogs\UPSmanage.log
rem echo %ERRORLEVEL%
IF %ERRORLEVEL% EQU 0 GOTO STEP3
IF %ERRORLEVEL% EQU 1 GOTO STEP3
rem 0 - locked ok, 1 - already locked by this id
goto STEP2

rem     ensure nothing is happening at the supervisor panel
:STEP3
echo Ensure nothing is happening at the supervisor panel...
echo releasing supervisor resources... >>c:\NCRLogs\UPSmanage.log
SSTManage /LS "APTRA Shutdown" 10000 >>c:\NCRLogs\UPSmanage.log
rem echo %ERRORLEVEL%
IF %ERRORLEVEL% EQU 0 GOTO STEP4
IF %ERRORLEVEL% EQU 1 GOTO STEP4
rem 0 - locked ok, 1 - already locked by this id

rem need to wait a little before retry to prevent wrong reply "1" from sstmanage:
echo Delay after unsuccessfull lock... >>c:\NCRLogs\UPSmanage.log 
C:\SSDS\SOFTUPD\choice.com /T:Y,10 >nul

goto STEP3

rem     reset the terminal to get it back in service.
rem     START the program in a separate session to allow this script
rem     to complete, otherwise this job will never complete at the server.
:STEP4
ECHO    ** RESETTING THE TERMINAL **
echo all resources released, restarting... >>c:\NCRLogs\UPSmanage.log
date /T >>c:\NCRLogs\UPSmanage.log
time /T >>c:\NCRLogs\UPSmanage.log

SSTManage.exe %STARTUP_MODE% 10000 >>c:\NCRLogs\UPSmanage.log

rem	response to the calling program is not required now; 
rem	so, we can just exit.
exit

[GOST76]

Создал я батник и запихнул в него все что ты написал. Тестировал несколько раз, да он плавно гасит аптру и гасит банкомат (только не знаешь как сделать чтобы в конце не висел экран что питание компьютера может быть отключено, а по нормальному отключался), но вот того что я ждал так не произошло, не отслеживает он наличии операции. Несколько раз успел я смоделировать ситуацию таким образом, что в момент отправки/получении данных на хост/с хоста аппликация потухла, в остальных случаях она тухла когда я двигался по меню сценария. Есть что добавить?

Потестирую дальше , потом напишу.

[sockspy]

(только не знаешь как сделать чтобы в конце не висел экран что питание компьютера может быть отключено, а по нормальному отключался)

http://forum.oszone.net/post-390508.html
http://support.microsoft.com/kb/810903/ru

[Shoroh]

sockspy

[olegka_n]

Создал я батник и запихнул в него все что ты написал. Тестировал несколько раз, да он плавно гасит аптру и гасит банкомат (только не знаешь как сделать чтобы в конце не висел экран что питание компьютера может быть отключено, а по нормальному отключался), но вот того что я ждал так не произошло, не отслеживает он наличии операции. Несколько раз успел я смоделировать ситуацию таким образом, что в момент отправки/получении данных на хост/с хоста аппликация потухла, в остальных случаях она тухла когда я двигался по меню сценария. Есть что добавить?
Потестирую дальше , потом напишу.

Читаем текст батника внимательно и видим в конце каждого блока снасала идут две проверки условия:
IF %ERRORLEVEL% EQU 0 GOTO STEP3
IF %ERRORLEVEL% EQU 1 GOTO STEP3
а затем строчка с пояснением
rem 0 - locked ok, 1 - already locked by this id
т.е. нужно выбрать нужное, а ненужную сточку с проверкой условия закоментарить.
Я не совсем помню какой вариант нужно выбрать - у нас испльзуется только на одном банкомате и пока карта в банкомате он не гасится

[GOST76]

в общем пашет батник эдакий, спасибо за информацию, в банкомате я нашел такой же только на перезагрузку Аптры по пути C:\SSDS\SOFTUPD\restart.cmd, от сюда по ходу ноги и растут.

[olegka_n]

1. Запустить банкомат в административном режиме (пользователь abcd…) и войти в ‘Control Panel’, где выбрать иконку ‘Power Options’. Перейти в раздел настройки UPS
2. Выбрать тип UPS и порт, к которому он подключен, используя кнопку ‘Select’ –
3. Выполнить настройку обработки сообщений от UPS, переход по кнопке ‘Configure’ (рис.2), выставив «галочки» (три нижние)
4. Установить модуль обработки предупреждения о потере питания ‘Alarm’ и рабочий каталог, с.м. рис.4.
5. В качестве пользователя для запуска приложения ‘UPSshutdown.cmd’ задать “SYSTEM” при запросе пароля нажать <Enter>. Все «галочки» должны быть удалены
Перед настойкой синхронизации банкомата с UPS надо поместить файл UPSshutdown.cmd в каталог “C:\ADMTOOLS”.


и тогда банкомат выключается полностью

[GOST76]

3. Выполнить настройку обработки сообщений от UPS, переход по кнопке ‘Configure’ (рис.2), выставив «галочки» (три нижние)

В этом случае третьей и последней является галочка "Finally, turn off the UPS" т.е. вырубается ИБП и только тогда гаснит банкомат, питалова по любому не автоматически отключается самим банкоматом, а ИБП, но вариант мне подходит, спасибо.

[olegka_n]

Да не за что, могу с рисунками выложить если что)
Я сам схему давно пользовал, а тут пришлось вспоминать - настроил и сюда дописал. Я инструкцию написал для того чтобы чел "далекий" от компов вообще смог настроить удаленный банкомат.

[GOST76]

Мне вот как раз для таких ребят и нужно будет сварганить инструкцию, может выложишь если не трудно с картинками.

[olegka_n]

смотри во вложении

[GOST76]

Класс, спасибо!!!